123456789101112131415161718192021222324252627282930313233343536373839404142434445464748495051525354555657585960616263646566676869707172737475767778798081828384858687888990919293949596979899100101102103104105 |
- /*
- * Copyright (C) 2009 Uwe Hermann <uwe@hermann-uwe.de>
- *
- * This library is free software: you can redistribute it and/or modify
- * it under the terms of the GNU Lesser General Public License as published by
- * the Free Software Foundation, either version 3 of the License, or
- * (at your option) any later version.
- *
- * This library is distributed in the hope that it will be useful,
- * but WITHOUT ANY WARRANTY; without even the implied warranty of
- * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
- * GNU Lesser General Public License for more details.
- *
- * You should have received a copy of the GNU Lesser General Public License
- * along with this library. If not, see <http://www.gnu.org/licenses/>.
- */
- /* Generic linker script for STM32 targets using unicore-mx. */
- /* Memory regions must be defined in the ld script which includes this one. */
- /* Enforce emmition of the vector table. */
- EXTERN (vector_table)
- /* Define the entry point of the output file. */
- ENTRY(reset_handler)
- /* Define sections. */
- SECTIONS
- {
- .text : {
- *(.vectors) /* Vector table */
- *(.text*) /* Program code */
- . = ALIGN(4);
- *(.rodata*) /* Read-only data */
- . = ALIGN(4);
- } >rom
- /* C++ Static constructors/destructors, also used for __attribute__
- * ((constructor)) and the likes */
- .preinit_array : {
- . = ALIGN(4);
- __preinit_array_start = .;
- KEEP (*(.preinit_array))
- __preinit_array_end = .;
- } >rom
- .init_array : {
- . = ALIGN(4);
- __init_array_start = .;
- KEEP (*(SORT(.init_array.*)))
- KEEP (*(.init_array))
- __init_array_end = .;
- } >rom
- .fini_array : {
- . = ALIGN(4);
- __fini_array_start = .;
- KEEP (*(.fini_array))
- KEEP (*(SORT(.fini_array.*)))
- __fini_array_end = .;
- } >rom
- /*
- * Another section used by C++ stuff, appears when using newlib with
- * 64bit (long long) printf support
- */
- .ARM.extab : {
- *(.ARM.extab*)
- } >rom
- .ARM.exidx : {
- __exidx_start = .;
- *(.ARM.exidx*)
- __exidx_end = .;
- } >rom
- . = ALIGN(4);
- _etext = .;
- .data : {
- _data = .;
- *(.data*) /* Read-write initialized data */
- . = ALIGN(4);
- _edata = .;
- } >ram AT >rom
- _data_loadaddr = LOADADDR(.data);
- .bss : {
- _bss = .;
- *(.bss*) /* Read-write zero initialized data */
- *(COMMON)
- . = ALIGN(4);
- _ebss = .;
- } >ram
- /*
- * The .eh_frame section appears to be used for C++ exception handling.
- * You may need to fix this if you're using C++.
- */
- /DISCARD/ : { *(.eh_frame) }
- . = ALIGN(4);
- end = .;
- }
- PROVIDE(_stack = ORIGIN(ram) + LENGTH(ram));
|