MEMORY
{
    FLASH(rx)  : ORIGIN = 0x08000000, LENGTH = 0xC0000
    DFLASH(RX) : ORIGIN = 0x080C0000, LENGTH = 0x40000

    SRAM (rwx) : ORIGIN = 0x20000000, LENGTH = 0x50000
    SDRAM(rwx) : ORIGIN = 0xC0000000, LENGTH = 0x800000
}
GROUP(libgcc.a libc.a libm.a)

SECTIONS
{
    .text :
    {
        _start_text = .;
        KEEP(*(.isr_vector))
        *(.init)
        *(.fini)
        *(.text*)
        *(.rodata*)
        . = ALIGN(4);
        _end_text = .;
    } > FLASH

    .edidx :
    {
        . = ALIGN(4);
        *(.ARM.exidx*)
    } > FLASH

    _stored_data = .;

    .data : AT (_stored_data)
    {
        _start_data = .;
        *(.data*)
        . = ALIGN(4);
        _end_data = .;
    } > SRAM

    .bss :
    {
        _start_bss = .;
        *(.bss*)
        *(COMMON)
        . = ALIGN(4);
        _end_bss = .;
        _end = .;
        end = .;
    } > SRAM
}

PROVIDE(_end_stack  = ORIGIN(SRAM) + LENGTH(SRAM));
PROVIDE(_start_heap = ORIGIN(SDRAM) + 7M);
